Piano World Home Page Forums Our Most Popular Forums Digital Pianos - Electronic Pianos - Synths & Keyboards Need advice on MIDI add-on for Kawai VPC1

#include <ADC.h>

#define HALF_PEDAL A21

// On pedal-down the F10H pedal produces a decreasing voltage
// The following is the 8-bit value read by ADC where the pedal, on pedal-down motion, should produce MIDI value of 1
#define HIGH_PEDAL_LIMIT 192

// the 8-bit value read by ADC where the pedal should produce MIDI value of 127
#define LOW_PEDAL_LIMIT 85

byte lastSustainValue;
byte lastSustainVoltage;
byte ccValue[256];

byte voltage;
byte currentPedalValue;


ADC *adc = new ADC();

void setup() {
  pinMode(HALF_PEDAL, INPUT); // Kawai F10H half-pedal

  double pedalSegment = 127.0 / (HIGH_PEDAL_LIMIT - LOW_PEDAL_LIMIT);

  // pre-calculate the ADC voltage (8-bit value) to MIDI value map
  for (int i = 0; i < 256; i++) {
    if (i < LOW_PEDAL_LIMIT) {
      ccValue[i] = 127;
    } else if (i > HIGH_PEDAL_LIMIT) {
      ccValue[i] = 0;
    } else {
      byte value = (byte) (127 - (pedalSegment * (i - LOW_PEDAL_LIMIT)) + 0.5);
      ccValue[i] = value < 0 ? 0 : value;
    }
  }

  lastSustainValue = 0;
  lastSustainVoltage = 0;

  adc->adc0->setAveraging(16);
  adc->adc0->setResolution(8);
  adc->adc0->setConversionSpeed(ADC_CONVERSION_SPEED::VERY_LOW_SPEED);
  adc->adc0->setSamplingSpeed(ADC_SAMPLING_SPEED::VERY_LOW_SPEED);
  adc->startContinuous(HALF_PEDAL);

}

void loop() {
  checkSustainPedal();
  usbMIDI.send_now();
}

void checkSustainPedal() {
  voltage = (byte)adc->adc0->analogReadContinuous();
  if (voltage != lastSustainVoltage) {
    lastSustainVoltage = voltage;
    currentPedalValue = ccValue[voltage];
    if (currentPedalValue != lastSustainValue) {
      lastSustainValue = currentPedalValue;
      usbMIDI.sendControlChange(64, currentPedalValue, 1);
    }
  }
}